/*
 * MIT License
 *
 * Copyright (c) 2019 Alexey Edelev <semlanik@gmail.com>
 *
 * This file is part of NeuralNetwork project https://git.semlanik.org/semlanik/NeuralNetwork
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy of this
 * software and associated documentation files (the "Software"), to deal in the Software
 * without restriction, including without limitation the rights to use, copy, modify,
 * merge, publish, distribute, sublicense, and/or sell copies of the Software, and
 * to permit persons to whom the Software is furnished to do so, subject to the following
 * conditions:
 *
 * The above copyright notice and this permission notice shall be included in all copies
 * or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED,
 * INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR
 * PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE
 * FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR
 * OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
 * DEALINGS IN THE SOFTWARE.
 */

import QtQuick 2.11
import QtQuick.Window 2.11
import QtQuick.Controls 2.12
import QtQuick.Controls.Styles 1.0

import snakesimulator 1.0

ApplicationWindow {
    id: root
    visible: true
    property int tileSize: 20
    width: field.width*tileSize + sideBar.width
    height: field.height*tileSize

    Rectangle {
        color: "#565656"
        anchors.fill: parent
    }

    Repeater {
        model: snake.pointsData.length
        Rectangle {
            color: "#ffffff"
            x: snake.pointsData[model.index].x*tileSize
            y: snake.pointsData[model.index].y*tileSize
            width: tileSize
            height: tileSize
        }
    }

    Rectangle {
        color: "#99ee99"
        x: field.food.x*tileSize
        y: field.food.y*tileSize
        width: tileSize
        height: tileSize
    }

    Rectangle {
        id: sideBar
        width: speedControl.width + contentColumn.anchors.margins*2
        color: "#000000"
        anchors {
            right: parent.right
            top: parent.top
            bottom: parent.bottom
        }
        Column {
            id: contentColumn
            anchors.fill: parent
            anchors.margins: 10
            spacing: 10
            Text {
                font.pointSize: 14
                font.weight: Font.Bold
                color: "#ffffff"
                text: "Generation: " + stats.generation
            }
            Text {
                font.pointSize: 14
                font.weight: Font.Bold
                color: "#ffffff"
                text: "Individual: " + stats.individual
            }
            Text {
                font.pointSize: 14
                font.weight: Font.Bold
                color: "#ffffff"
                text: "Move: " + stats.move
            }
            Text {
                font.pointSize: 14
                font.weight: Font.Bold
                color: "#ffffff"
                text: "Speed: " + (speedControl.value > 10 ? "\u221e" : speedControl.value)
            }
            Slider {
                id: speedControl
                value: 5
                from: 1
                stepSize: 1.0
                to: 11
                snapMode: Slider.SnapAlways
                onValueChanged: {
                    changeTimer.restart()
                }

                background: Rectangle {
                    x: speedControl.leftPadding
                    y: speedControl.topPadding + speedControl.availableHeight / 2 - height / 2
                    implicitWidth: 200
                    implicitHeight: 4
                    width: speedControl.availableWidth
                    height: implicitHeight
                    radius: 2
                    color: "#bdbebf"

                    Rectangle {
                        x: 0
                        width: speedControl.position * parent.width
                        height: parent.height
                        color: speedControl.value <= 10 ? "lightgreen" : "#003b6f"
                        radius: 2
                    }
                }
                Timer {
                    id: changeTimer
                    repeat: false
                    interval: 200
                    onTriggered: {
                        client.setSpeed(speedControl.value > 10 ? 0 : speedControl.value)
                    }
                }
            }
        }


        // it will play best in the loop afte naturel selection finished
        CheckBox {
            id: playBestCheckbox
            anchors.margins: 10
            anchors.bottom: bestBtn.top
            anchors.right: parent.right
            width: indicator.width + 170
            checked: true
            onCheckedChanged: {
                client.playBestInLoop(playBestCheckbox.checked)
            }

            contentItem: Text {
                id: text
                color: "white"
                text: "Repeat Best"
                wrapMode: Text.NoWrap
                anchors.left: playBestCheckbox.indicator.right
                anchors.leftMargin: 10
                anchors.right: undefined
                verticalAlignment: Text.AlignVCenter
            }

            Component.onCompleted: {
                client.playBestInLoop(playBestCheckbox.checked)
            }
        }

        Button {
            id: bestBtn
            anchors.margins: 10
            anchors.bottom: parent.bottom
            anchors.right: parent.right

            width: 100
            height: 50

            Rectangle {
                anchors.fill: parent
                enabled: isPlaying.state
                color: isPlaying.state ? "#003b6f" : "lightgreen"
            }

            Text {
                anchors.centerIn: parent
                horizontalAlignment: Text.AlignVCenter
                text: "Play best"
            }

            onClicked: {
                client.playBest()
            }
        }
    }

    Connections {
        target: field
        onWidthChanged: {
            console.log("New width: " + field.width)
        }
    }
}